/* HLSL vignetting shader
* by vtastek
* This shader creates a lens effect that illustrates corners of an image
* less saturated and darker,
* the effect is known as vignetting in photography
* used to get viewer's attention in center
*/

static const float radius = 3.8;
static const float darkness = 0.15;

float2 rcpres;
static const float raspect = rcpres.x / rcpres.y;

texture lastpass;
sampler s0 = sampler_state { texture=<lastpass>; addressu = clamp; addressv = clamp; magfilter = linear; minfilter = none; };

float4 vignetteHLSL(float2 Tex : TEXCOORD0) : COLOR0 {
float4 vSample = tex2D(s0, Tex);
float2 inTex = (Tex - 0.5) * float2(1.0, raspect);
float vignette = 1 - dot(inTex, inTex);
vSample.rgb *= saturate(pow(vignette, radius) + darkness);
return vSample;
}


technique T0 < string MGEinterface="MGE XE 0"; >
{
pass { PixelShader = compile ps_2_0 vignetteHLSL(); }
}

// ---------------------------------------------------------------------------------------
//
// Film shader (Softlightx2 Version) for video to be used in Avery Lee's Virtualdub
// GPU Shader filter. v1.6 - 20.00.08© Jukka Korhonen from the original code by Avery Lee.
//
// ---------------------------------------------------------------------------------------
// http://www.loadusfx.net/virtualdub/filmfxguide.htm

// ------------ TWEAKABLE VARIABLES ------------
static const float Strenght = 1.0; // from 0.0 to 1.0
static const float BaseGamma = 2.2; // from 0.1 to 2.5
static const float Fade = 0.15; // from 0.0 to 0.5
static const float Contrast = 0.9; // from 0.6 to 1.0
static const float Saturation = 0.1; // from 0.25 to -0.25
static const float Bleach = 0.1; // from 0.0 to 1.0
static const float RedCurve = 10.0; // from 1.0 to 10.0
static const float GreenCurve = 5.5; // from 1.0 to 10.0
static const float BlueCurve = 1.0; // from 1.0 to 10.0
static const float BaseCurve = 1.0; // from 1.0 to 10.0
static const float EffectGammaR = 1.0; // from 0.1 to 2.5
static const float EffectGammaG = 1.0; // from 0.1 to 2.5
static const float EffectGammaB = 1.0; // from 0.1 to 2.5
static const float EffectGamma = 1.5; // from 0.1 to 2.5
static const float Linearization = 2.5; // from 1.0 to 2.5
// ------------ END OF TWEAKABLE VARIABLES ------------

texture lastpass;
sampler s0 = sampler_state { texture=<lastpass>; addressu = clamp; addressv = clamp; magfilter = point; minfilter = point; };

static const
float3x3 XYZ_RGB = {{+ 0.412453, + 0.357580, + 0.180423},
{+ 0.212671, + 0.715160, + 0.072169},
{+ 0.019334, + 0.119193, + 0.950227}};

float GetLuminance( const float3 rgb )
{
return dot( XYZ_RGB[1], rgb );
}

float4 FilmPass(float2 Tex : TEXCOORD0) : COLOR0
{
float4 B = tex2D(s0, Tex);
float4 G = B;
float4 H = 0.01;

B = pow(abs(B), Linearization);
B = lerp(H, B, Contrast);

float A = GetLuminance(B.rgb);
float4 D = A;

B = pow(abs(B), 1.0 / BaseGamma);

float a = RedCurve;
float b = GreenCurve;
float c = BlueCurve;
float d = BaseCurve;

float y = 1.0 / (1.0 + exp(a / 2.0));
float z = 1.0 / (1.0 + exp(b / 2.0));
float w = 1.0 / (1.0 + exp(c / 2.0));
float v = 1.0 / (1.0 + exp(d / 2.0));

float4 C = B;

D.r = (1.0 / (1.0 + exp(-a * (D.r - 0.5))) - y) / (1.0 - 2.0 * y);
D.g = (1.0 / (1.0 + exp(-b * (D.g - 0.5))) - z) / (1.0 - 2.0 * z);
D.b = (1.0 / (1.0 + exp(-c * (D.b - 0.5))) - w) / (1.0 - 2.0 * w);

D = pow(abs(D), 1.0 / EffectGamma);

float4 Di = 1.0 - D;

D = lerp(D, Di, Bleach);

D.r = pow(abs(D.r), 1.0 / EffectGammaR);
D.g = pow(abs(D.g), 1.0 / EffectGammaG);
D.b = pow(abs(D.b), 1.0 / EffectGammaB);

if (D.r < 0.5)
C.r = (2.0 * D.r - 1.0) * (B.r - B.r * B.r) + B.r;
else
C.r = (2.0 * D.r - 1.0) * (sqrt(B.r) - B.r) + B.r;

if (D.g < 0.5)
C.g = (2.0 * D.g - 1.0) * (B.g - B.g * B.g) + B.g;
else
C.g = (2.0 * D.g - 1.0) * (sqrt(B.g) - B.g) + B.g;

if (D.b < 0.5)
C.b = (2.0 * D.b - 1.0) * (B.b - B.b * B.b) + B.b;
else
C.b = (2.0 * D.b - 1.0) * (sqrt(B.b) - B.b) + B.b;

float4 F = lerp(B, C, Strenght);

F = (1.0 / (1.0 + exp(-d * (F - 0.5))) - v) / (1.0 - 2.0 * v);

float r2R = 1.0 - Saturation;
float g2R = 0.0 + Saturation;
float b2R = 0.0 + Saturation;

float r2G = 0.0 + Saturation;
float g2G = (1.0 - Fade) - Saturation;
float b2G = (0.0 + Fade) + Saturation;

float r2B = 0.0 + Saturation;
float g2B = (0.0 + Fade) + Saturation;
float b2B = (1.0 - Fade) - Saturation;

float4 iF = F;

F.r = (iF.r * r2R + iF.g * g2R + iF.b * b2R);
F.g = (iF.r * r2G + iF.g * g2G + iF.b * b2G);
F.b = (iF.r * r2B + iF.g * g2B + iF.b * b2B);

float N = GetLuminance(F.rgb);
float4 Cn = F;

if (N < 0.5)
Cn = (2.0 * N - 1.0) * (F - F * F) + F;
else
Cn = (2.0 * N - 1.0) * (sqrt(F) - F) + F;

Cn = pow(abs(Cn), 1.0 / Linearization);

float4 Fn = lerp(B, Cn, Strenght);
return Fn;
}

technique T0 < string MGEinterface="MGE XE 0"; >
{
pass { PixelShader = compile ps_3_0 FilmPass(); }
}